;
;  compute chi_B along line of sight (here the x direction)
;
x=var.x
y=var.y
z=var.z
nx=n_elements(x)
ny=n_elements(y)
nz=n_elements(z)
nk=180
kmax=13.
kx=grange(-kmax,kmax,nk)
Bxrms=mean(var.bb(*,*,*,0)^2)^.5
;
ii=complex(0.,1.)
expkx=complexarr(nx,nk)
expkx_phi=complexarr(nx,nk)
for ik=0,nk-1 do expkx(*,ik)=exp(ii*kx(ik)*x)
;
RM=fltarr(ny,nz)
BBk=complexarr(nk,ny,nz)
PPk=complexarr(nk,ny,nz)
BBk_phi=complexarr(nk,ny,nz)
PPk_phi=complexarr(nk,ny,nz)
for m=0,ny-1 do begin
for n=0,nz-1 do begin
  Bx=reform(var.bb(*,m,n,0))
  By=reform(var.bb(*,m,n,1))
  Bz=reform(var.bb(*,m,n,2))
  ;experiment to remove mean Bperp
    By=By-mean(By)
    Bz=Bz-mean(Bz)
  BB=complex(By,Bz)
  ;
  phi=integr(Bx,x=x)/Bxrms
  for ik=0,nk-1 do expkx_phi(*,ik)=exp(ii*kx(ik)*phi)
  for ik=0,nk-1 do BBk(ik,m,n)=total(BB*expkx(*,ik))
  for ik=0,nk-1 do PPk(ik,m,n)=total(BB^2*expkx(*,ik))
  for ik=0,nk-1 do BBk_phi(ik,m,n)=total(BB*expkx_phi(*,ik))
  for ik=0,nk-1 do PPk_phi(ik,m,n)=total(BB^2*expkx_phi(*,ik))
  RM[m,n]=phi(nx-1)
  ;
endfor
endfor
;
BBkm=total(total(BBk,3),2)/(ny*nz)
PPkm=total(total(PPk,3),2)/(ny*nz)
!p.multi=[0,1,2]
!x.range=[-10,10]*1.4
plot,kx,abs(BBkm)
plot,kx,abs(PPkm)
save,file='BBk_PPk_phix.sav',kx,BBk,PPk,BBk_phi,PPk_phi,RM,nk,BBkm,PPkm,Bxrms
;
!p.multi=0
!x.range=0
!y.range=0
END