;$Id: pflucts.pro,v 1.2 2007/09/29 06:41:04 brandenb Exp $
;
;  plot alpa and eta results from time series
;
pc_read_ts,o=o
;
;  set minimum time after which averaging begins
;
t2=1e30
spawn,'touch parameters.pro'
@parameters
@data/index.pro
@data/testfield_info.dat
default,run,''
;
;  introduce abbreviations
;
tt=o.t
urms=o.urms
nt=n_elements(tt)
alp=fltarr(nt,2,2) & alpm=fltarr(2,2) & alprms=fltarr(2,2)
eta=fltarr(nt,2,2) & etam=fltarr(2,2) & etarms=fltarr(2,2)
;
;  alpha tensor
;
alp(*,0,0)=o.alp11
alp(*,1,0)=o.alp21
;
;  eta tensor as in EMF_i = ... -eta_ij J_j
;  so these new etas are also referred to as eta^*
;
eta(*,0,1)=-o.eta11
eta(*,1,1)=-o.eta21
;
;  read extra fields (if itestfield eq 'B11-B22'
;  as opposed to just itestfield eq 'B11-B21')
;
if itestfield eq 'B11-B22' then begin
  alp(*,0,1)=o.alp12
  alp(*,1,1)=o.alp22
  eta(*,0,0)=+o.eta12
  eta(*,1,0)=+o.eta22
endif
;
;  range of time where to do the analysis
;
tmin=min(tt)
tmax=max(tt)
default,t1,(tmin+tmax)/2.
good=where(tt gt t1 and tt lt t2)
kf=5.
;
!p.charsize=2.6
!p.multi=[0,2,4]
!x.title='!6'
;
;  give modified alpmax values in parameters.pro file
;
for i=0,1 do begin
for j=0,1 do begin
  !p.title='!7a!6!d'+str(i)+str(j)+'!n'
  fluct_stat,tt,/plo,alp(*,i,j),fm,frms,good=good
  alpm(i,j)=fm & alprms(i,j)=frms
endfor
endfor
;
for i=0,1 do begin
for j=0,1 do begin
  !p.title='!7g!6!d'+str(i)+str(j)+'!n'
  fluct_stat,tt,/plo,eta(*,i,j),fm,frms,good=good
  etam(i,j)=fm & etarms(i,j)=frms
endfor
endfor
;
print,alprms
print
print,etarms
print
;
alprms_all=sqrt(.25*total(alprms^2))
etarms_all=sqrt(.25*total(etarms^2))
;
fo='(a,e8.2)'
openw,1,'alphaeta_rms.pro'
printf,1,'alprms_all=',alprms_all,fo=fo
printf,1,'etarms_all=',etarms_all,fo=fo
close,1
;
spawn,'cat alphaeta_rms.pro'
spawn,'cvs add alphaeta_rms.pro'
END